[Soft] NT Sleep. Описание программы

Я настолько нуб, что не знаю как запускать прогу NtSleep - 4 кв ? )).
Винда xp.
Что надо прописать в командной строке, что б ее запустить ?

 

А какие именно ухищрения не помогли?

В случае с Шоком-2 вопрос обычно решается включением для EXE-шника игры вертикальной синхронизации в настройках видео-драйвера. Ну и всякие там сглаживания/анизотроп. фильтрацию можно добавить до кучи...

По крайней мере, ещё недавно это помогало.

 

В самой игре этих настроек нет, файл конфигурации в папке игры тож что-то не нашел.

Вопрос стоит до сих пор, вообще-то как запустит прогу?

 

Разумеется, нет. Потому я и говорил про настройки видео-драйвера. В них надо создать профиль для SHOCK2.EXE и прописать там вертик. синхронизацию (и всякие сглаживания, если потребуется).

ИМХО, замедлялка для Шока-2 не нужна.

 

Подтверждаю, не нужна. Работает нормально без замедления, достаточно только DEfix для мультипроцессорников поставить.

 

Профиль для SHOCK2.EXE, не создавал. Выставил все опции, которые посоветовали, в настройках Catalyst CC. Спасиб.

 

Подскажите, как пользоваться этой программой из коммандной строки\batch-файла? Как ей там указать что запускать?

 

Батник:

Код:

@ECHO OFF

chcp 1251

"C:\Program Files (x86)\DAEMON Tools Lite\dtlite.exe" -unmount 0 -mount 0,"X:\Игры\Commandos - Behind Enemy Lines\Commandos.mds"

start /d "E:\Commandos - Behind Enemy Lines\" Y:\Игры\TOOLS\NtSleep\NtSleep.exe "COMANDOS.EXE"

"C:\Program Files (x86)\DAEMON Tools Lite\dtlite.exe" -unmount 0

Не могу понять как ему объяснить, что COMANDOS.exe - параметр для NtSleep.exe

Если создать для NtSleep ярлык и туда также прописать путь - запускается как надо. Батник же запускает по очереди NtSleep.exe без параметров, и потом Comandos.exe.

Пробовал прописывать полный путь к COMANDOS.exe, по-разному ставить кавычки - результат либо такой же, либо вообще ничего не запускается (это если путь к ntsleep.exe в кавычки не взять).

 

Код:

Y:\Игры\TOOLS\NtSleep\NtSleep.exe "E:\Commandos - Behind Enemy Lines\COMANDOS.EXE"

Код:

cd "E:\Commandos - Behind Enemy Lines"
Y:\Игры\TOOLS\NtSleep\NtSleep.exe COMANDOS.EXE

 

Siberian_GRemlin, к сожалению, так не работает.

Решил проблему запуская из батника ярлык на NtSleep, через который всё работает как надо. Сдаётся мне, проблема не в программе и батнике, а в Windows 7.

 

Есть ещё файлы сценариев (.CMD)

 

Тем временем, автор программы выпустил новую версию, с поддержкой указания значения таймера из коммандной строки и гарантированной работой на Windows 7.

http://imasters.org.ru/viewtopic.php?id=17

Всё работает, ура!

 

Не работает. Остаётся 100% загрузка в Screamer 2, Need for speed III Hot Pursuit и High Stakes.
Зато тормоза появились.

 

максимальное значение микросекунд - 32? Запустил s.t.o.r.m. - все равно слишком быстро.
чем нужно компилировать NtSleep.asm?

 

QQQin, FASM последней версии сгодится.

 

FASM я пробовал
Чтобы им скомпилировать надо еще скачать 3 файла. Во время компиляции в одном из них вылазит ошибка

 

QQQin, ты имеешь в виду kernel32.inc, ntdll.inc и msvcrt.inc? Скорее всего какую-то из них не ту скачал)
Вот исходник, не требующий этих файлов, вроде компилится (у меня FASM 1.68). Импорт функций задан вручную, а не из *.inc файлов.
Тыкнуть

Код:

;made by Antares
;http://imasters.org.ru
;демонстрация снижения нагрузки на процессор \ замедление процесса
;пример использует "родные" функции Windows XP (NtSuspendProcess и NtResumeProcess)
;если придумаете лучший алгоритм или усовершенствуете этот, дайте знать, мне будет очень интересно

       format PE console 5.01 at 10000h
       entry start
	     include 'include\win32ax.inc'

	     section 'x86' code readable executable writeable
	     data    import
	     library kernel32, 'kernel32.dll',\
		     ntdll,    'ntdll.dll',\
		     msvcrt,   'msvcrt.dll',\
		     user32,   'user32.dll',\
		     winmm,    'winmm.dll'
	     import msvcrt,\
		     memset,		'memset',\
		     __getmainargs,	'__getmainargs',\
		     _strcmpi,		'_strcmpi',\
		     strlen,		'strlen',\
		     atoi,		'atoi',\
		     strstr,		'strstr',\
		     strrchr,		'strrchr'
	     import  kernel32,\
		     CreateWaitableTimerW, 'CreateWaitableTimerW',\
		     SetWaitableTimer,	   'SetWaitableTimer',\
		     GetCommandLine,	   'GetCommandLineA',\
		     CreateProcess,	   'CreateProcessA',\
		     WaitForSingleObject,  'WaitForSingleObject',\
		     CancelWaitableTimer,  'CancelWaitableTimer',\
		     lstrcpyn,		   'lstrcpynA',\
		     SetCurrentDirectory,  'SetCurrentDirectoryA',\
		     GetCurrentDirectory,  'GetCurrentDirectoryA'
	     import  ntdll,\
		     NtSuspendProcess,	   'NtSuspendProcess',\
		     NtResumeProcess,	   'NtResumeProcess',\
		     NtClose,		   'NtClose'
	     ;include 'INCLUDE\apiu\kernel32.inc'
	     ;include 'INCLUDE\apiu\ntdll.inc'
	     ;include 'INCLUDE\apiu\msvcrt.inc'
	     ;include 'INCLUDE\apiu\user32.inc'
	     ;include 'INCLUDE\apia\winmm.inc'
	     end data

	 align 4

	 ptimer 	 db '/timer=',0
	 hTimer 	 dd ?
	 liDueTime	 dq -1000000	; (Одна секунда равна десяти миллионам интервалов по 100 нс)
				       ; -10000000  = 1 секунде
				       ; -100000000 = 10 секундам
	EnvV		 dd ? ; environment variables
	ArgV		 dd ? ; argument vectors
	ArgC		 dd ? ; argument count

       proc start uses esi edi ebx
	local sui STARTUPINFO,\
	      pin PROCESS_INFORMATION

	xor	ebx, ebx

	cinvoke memset, addr sui, ebx, sizeof.STARTUPINFO+sizeof.PROCESS_INFORMATION

	cinvoke __getmainargs, ArgC, ArgV, EnvV, ebx	; "парсинг" командной строки

	mov	edx, [ArgV]
	mov	edi, [edx+8]	; параметр
	mov	esi, [edx+4]	; запускаемый файл
	test	esi, esi
	jz	.exit
	test	edi, edi
	jz	.exit

	cinvoke _strcmpi, esi, ptimer
	dec	eax
	test	eax, eax
	jnz	.exit
	cinvoke strlen, ptimer
	add	esi, eax
	cinvoke atoi, esi      ; перевод значения из ASCII в DWORD
	mov	dword[ptimer], eax
	cmp	eax, 32        ; значение таймера больше 32 не принимаются
	jg	.exit

	stdcall AppSetCurrentDirectory, edi	; установка текущей директории

	invoke	CreateWaitableTimerW, NULL, FALSE, NULL 			 ;создать ждущий таймер
	mov	[hTimer], eax							 ;сохранить хэндл
	test	eax, eax
	jz	.error

	invoke	SetWaitableTimer, [hTimer], liDueTime, dword[ptimer], NULL, NULL, TRUE	    ;устанавливаем таймер
	test	eax, eax
	jz	.error

	invoke	GetCommandLine
	cinvoke strstr, eax, edi

	invoke	CreateProcess, edi, eax, ebx, ebx, ebx, NORMAL_PRIORITY_CLASS, ebx, ebx, addr sui, addr pin
	test	eax, eax
	jz	.error

 @@:
	invoke	NtSuspendProcess, [pin.hProcess]	  ;приостановить процесс
	invoke	WaitForSingleObject, [hTimer], -1	  ;выждать n микросекунд - нечего напрасно процессор грузить
	invoke	NtResumeProcess,  [pin.hProcess]	  ;возобновить процесс
	invoke	WaitForSingleObject, [pin.hThread], 1	  ;проверка, работает ли процесс? одновременно "даем глоток воздуха"

	test	eax, eax
	jnz	@b					  ;eax=TRUE значит работает, в начало цикла


	invoke	NtClose, [pin.hThread]		      ;закрываем\освобождаем хендлы
	invoke	NtClose, [pin.hProcess] 	      ;закрываем\освобождаем хендлы
 .exit:
	xor	eax, eax
	ret

 .error:
	invoke	CancelWaitableTimer, [hTimer]
	ret
       endp

proc	AppSetCurrentDirectory uses esi, hString
	local	sTemp[1024]:BYTE

	lea	esi, [sTemp]
	cinvoke strrchr, [hString], ('\')	; ищет последний символ \ в строке
	test	eax, eax
	jz	@f
	sub	eax, [hString]
	inc	eax
	invoke	lstrcpyn, esi, [hString], eax
	invoke	SetCurrentDirectory, esi
	ret

	@@:
	invoke	GetCurrentDirectory, 1024, esi
	invoke	SetCurrentDirectory, esi
	ret
endp

 

Версия программы с максимальным значением микросекунд 999

 

QQQin, S.T.O.R.M теперь работает нормально с более высоким значением микросекунд ждущего таймера? И если да, то при каком значении на твоем компьютере?)